home *** CD-ROM | disk | FTP | other *** search
/ Libris Britannia 4 / science library(b).zip / science library(b) / INFO / XFDISK.ZIP / KEYCODE.BAS < prev    next >
BASIC Source File  |  1991-08-29  |  3KB  |  54 lines
  1. 100 ' KEYCODE.BAS
  2. 110 '
  3. 120 ' ╔═══════════════════════════════════════════════════════════════════════╗
  4. 130 ' ║ REFERENCE:                                                            ║
  5. 140 ' ║   PC Magazine DOS Power Tools (techniques, tricks, and utilities),    ║
  6. 150 ' ║   Paul Somerson, Bantam Computer Books, June 1988, page 466           ║
  7. 160 ' ║                                                                       ║
  8. 170 ' ║ The program will also display the character and code for the extended ║
  9. 180 ' ║ IBM character set, i.e, those with values from 128 thru 255.  Display ║
  10. 190 ' ║ of these characters and codes require pressing the ALT key and then   ║
  11. 200 ' ║ using the numeric key pad to enter the value from 128 thru 255.  The  ║
  12. 210 ' ║ character and code is then displayed upon release of the ALT key.     ║
  13. 220 ' ║                                                                       ║
  14. 230 ' ║ This version is a refinement of the program presented in the book.    ║
  15. 240 ' ║ The key codes of all the keys are displayed.  Mnemonics are displayed ║
  16. 250 ' ║ for those special keys that BASIC interprets as screen commands.      ║
  17. 260 ' ║                                                                       ║
  18. 270 ' ║ Written by:  Dennis W. Person                  Date:  August 29, 1991 ║
  19. 280 ' ║              6828 Devonshire Drive                                    ║
  20. 290 ' ║              Canton, Michigan  48187-2613                             ║
  21. 300 ' ╚═══════════════════════════════════════════════════════════════════════╝
  22. 310 '
  23. 320 KEY OFF                           :REM turn off function keys
  24. 330 FOR A%=1 TO 10:KEY A%,"":NEXT A%  :REM clear key assignments
  25. 340 '
  26. 350 COLOR 14,0,0:CLS :REM set text color to yellow w/ black background & border
  27. 360 LOCATE ,,1,0,7   :REM turn cursor on and set block cursor
  28. 370 '
  29. 390 PRINT "Press any key to display code(s) or ESC to end ? ";
  30. 400 I$=INKEY$:IF I$="" GOTO 400 :REM loop until key is pressed
  31. 410 '
  32. 420   IF I$=CHR$(7)   THEN PRINT "BEL"; :GOTO 570  :' CTRL-G
  33. 430   IF I$=CHR$(9)   THEN PRINT "TAB"; :GOTO 570  :' CTRL-I
  34. 440   IF I$=CHR$(10)  THEN PRINT "LF "; :GOTO 570  :' CTRL-J
  35. 450   IF I$=CHR$(11)  THEN PRINT "VT "; :GOTO 570  :' CTRL-K
  36. 460   IF I$=CHR$(12)  THEN PRINT "FF "; :GOTO 570  :' CTRL-L
  37. 470   IF I$=CHR$(13)  THEN PRINT "CR "; :GOTO 570  :' CTRL-M
  38. 480   IF I$=CHR$(27)  THEN PRINT "ESC"; :GOTO 570  :' CTRL-[
  39. 490   IF I$=CHR$(28)  THEN PRINT "^\ "; :GOTO 570  :' CTRL-\
  40. 500   IF I$=CHR$(29)  THEN PRINT "^] "; :GOTO 570  :' CTRL-]
  41. 510   IF I$=CHR$(30)  THEN PRINT "^^ "; :GOTO 570  :' CTRL-^
  42. 520   IF I$=CHR$(31)  THEN PRINT "^_ "; :GOTO 570  :' CTRL-_
  43. 530   IF I$=CHR$(32)  THEN PRINT "SPC"; :GOTO 570  :' Space character
  44. 540   IF I$=CHR$(127) THEN PRINT "DEL"; :GOTO 570  :' CTRL-BACKSPACE
  45. 550 '
  46. 560   IF LEN(I$)=1 THEN PRINT I$; ELSE PRINT "ext.  0 +";
  47. 570   PRINT ASC(RIGHT$(I$,1))
  48. 580 IF I$<>CHR$(27) GOTO 390
  49. 590 '
  50. 600 PRINT:COLOR 7,0,0 :REM restore default screen colors of white text
  51. 610 '                      with black background and black border
  52. 620 LOCATE ,,,7,7     :REM restore default underline cursor
  53. 630 SYSTEM
  54.